.export init
.feature c_comments

numL := $02 ; low byte of a 16-bit number
numH := $03 ; low byte of a 16-bit number
key_buf_len := $c6
key_buf := $0277
GETIN := $ffe4
CHROUT := $ffd2
CLRCHN := $e544

; initialisation: clear screen and set num to point to screen mem start
init:
  ; clear screen
  lda #$93
  jsr CHROUT

  ldy #$00
  lda #$04
  sta numH
  lda #$00
  sta numL
  jsr CLRCHN
  jmp loop

; main loop
loop:
  jsr GETIN
  beq loop

  cmp #$1d ; right arrow
  beq if_right
  cmp #$9d ; left arrow
  beq if_left
  cmp #$91 ; up arrow
  beq if_up
  cmp #$11 ; down arrow
  beq if_down
  cmp #$2d ; reset if - pressed
  beq if_reset
  cmp #$20 ; fill cell if space pressed
  beq if_space
  cmp #$30 ; end program if 0 pressed
  bne loop
  jmp end

if_right:
  jsr inc_num
  jmp loop

if_left:
  jsr dec_num
  jmp loop

if_up:
  lda #40
  jsr s16b
  jmp loop

if_down:
  lda #40
  jsr a16b
  jmp loop

if_reset:
  lda #$93
  jsr CHROUT
  jmp loop

if_space:
  ldx #$00
  lda (numL,x)
  cmp #$a0
  beq if_cell_filled
  jmp if_cell_empty
if_cell_filled:
  lda #$20
  jsr print_byte
  jmp loop
if_cell_empty:
  lda #$a0
  jsr print_byte
  jmp loop

; print byte in A at location in num
print_byte:
  ; init: store original A in X and push Y to stack
  tax
  tya
  pha
  txa

  ldy #$00
  sta (numL),y

  ; deinit: pull Y from stack and transfer original A from X to A
  pla
  tay
  txa
  rts

; adds A to num
a16b:
  clc
  adc numL
  sta numL
  lda #$00
  adc numH
  sta numH
  rts

; subtracts A from num
s16b:
  pha
  lda numL
  tsx
  inx
  sec
  sbc $0100,x
  sta numL
  lda numH
  sbc #$00
  sta numH
  pla
  rts

inc_num:
  inc numL
  beq inc_H
  rts
inc_H:
  inc numH
  rts

dec_num:
  pha

  dec numL
  lda numL
  cmp #$ff
  beq dec_H
  pla
  rts

dec_H:
  dec numH
  pla
  rts

end:
  brk